Code Base

Ответил в личку.

Обращаюсь ко всем, пишущим комментарии! Пожалуйста, не задавайте вопросов и не пишите просьбы, не относящиеся к индикатору MACD Elder Impulse Max. Для этого есть другие разделы сайта.

И личку не засоряйте просьбами, я не Старик Хоттабыч - желаний не исполняю. )))

Кому понравился индикатор, не забывайте повышать рейтинг. Кому не нравится или всё равно, просто проходите мимо.

Спасибо.

ind_buffer1[i]=iMA(Symbol(),FastMA_Timeframe,FastMA_Period,FastMA_Shift,FastMA_Method,FastMA_Price,i) - 
         iMA(Symbol(),SlowMA_Timeframe,SlowMA_Period,SlowMA_Shift,SlowMA_Method,SlowMA_Price,i);

Повторю еще раз:
В индикаторе MACD Elder Impulse Max используется СТАНДАРТНЫЙ индикатор MACD, созданный компанией MetaQuotes. Я согласен, что они использовали для построения гистограммы именно линию MACD, но я ничего с этим не могу поделать, потому и использовал то, что есть.

MACD = EMA(CLOSE, 12)-EMA(CLOSE, 26)

- http://codebase.mql4.com/ru/233

Это стандартный индикатор и им пользуются большинство трейдеров. Поэтому, я именно его и раскрасил.
Но, если серьезно, то я не вижу здесь принципиальной разницы(для раскрашивания), всё равно направленность движения столбиков практически одинакова в 99% случаев.

Ваш индикатор расчитывается: OSMA = MACD-SIGNAL, что полностью соответствует написанному в книгах Элдера. Гистограмма здесь нагляднее, чем в "стандартном" MACD и более выраженно показывает изменения сил быков и медведей.
Но для этой цели лично я предпочитаю пользоваться индикатором ELR. Это улучшенная модификация индикаторa Bulls Bears Power (http://codebase.mql4.com/ru/5415), который, в свою очередь, является неким симбиозом стандартных "Элдеровских" индикаторов Bulls Power и Bears Power. На мой взгляд, он более точен в определении силы, чем MACD, OsMA и т.п.(ИМХО). Думаю, стоит покрасить и его. :)

А Ваш индикатор ImpulseOsMA можно немного упростить:

//+------------------------------------------------------------------+
//|                                                 ImpulseOsMAx.mq4 |
//|                                                         MaxAgeNT |
//|                                         http:/forex.agent.zp.ua/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2012, MaxAgeNT"
#property link      "http:/forex.agent.zp.ua/"

#property indicator_separate_window
#property indicator_buffers 5
#property indicator_color1 Blue
#property indicator_color2 Red
#property indicator_color3 Red
#property indicator_color4 LimeGreen
#property indicator_color5 RoyalBlue //DeepSkyBlue

#property indicator_width1   1
#property indicator_width2   1
#property indicator_width3   2
#property indicator_width4   2
#property indicator_width5   2
//---- input parameters
extern int       FastEMA=12;
extern int       SlowEMA=26;
extern int       SignalEMA=9;
extern int       EMAPeriod=13;
//---- buffers
double ExtMapBuffer1[];
double ExtMapBuffer2[];
double ExtMapBuffer3[];
double ExtMapBuffer4[];
double ExtMapBuffer5[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- indicators
   SetIndexStyle(0,DRAW_LINE);
   SetIndexBuffer(0,ExtMapBuffer1);
   SetIndexStyle(1,DRAW_LINE);
   SetIndexBuffer(1,ExtMapBuffer2);
   SetIndexStyle(2,DRAW_HISTOGRAM);
   SetIndexBuffer(2,ExtMapBuffer3);
   SetIndexStyle(3,DRAW_HISTOGRAM);
   SetIndexBuffer(3,ExtMapBuffer4);
   SetIndexStyle(4,DRAW_HISTOGRAM);
   SetIndexBuffer(4,ExtMapBuffer5);
   
   IndicatorShortName("ImpulseOsMAx ("+FastEMA+","+SlowEMA+","+SignalEMA+","+EMAPeriod+")");
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   int i;
   int bCount;
   int    counted_bars=IndicatorCounted();
   double cur, prev, curMA, prevMA;
//----
   if(counted_bars>0) counted_bars--;
   bCount=Bars-counted_bars;
   for(i=0; i<bCount; i++)
      ExtMapBuffer1[i]=iMA(NULL,0,FastEMA,0,MODE_EMA,PRICE_CLOSE,i)-iMA(NULL,0,SlowEMA,0,MODE_EMA,PRICE_CLOSE,i);
   for(i=0; i<bCount; i++)
      ExtMapBuffer2[i]=iMAOnArray(ExtMapBuffer1,Bars,SignalEMA,0,MODE_EMA, i);
   for(i=0; i<bCount; i++)
   {
      cur = ExtMapBuffer1[i]-ExtMapBuffer2[i];
      prev = ExtMapBuffer1[i+1]-ExtMapBuffer2[i+1];
                 
      curMA=iMA(NULL,0,EMAPeriod,0,MODE_EMA,PRICE_CLOSE,i);
      prevMA=iMA(NULL,0,EMAPeriod,0,MODE_EMA,PRICE_CLOSE,i+1);

      if(cur>prev && curMA>prevMA)
      {
         ExtMapBuffer3[i]=0;
         ExtMapBuffer4[i]=cur;
         ExtMapBuffer5[i]=0;
      }
      else if(cur<prev && curMA<prevMA)
      {
         ExtMapBuffer3[i]=cur;
         ExtMapBuffer4[i]=0;
         ExtMapBuffer5[i]=0;
      }
      
      else if((cur<prev && curMA>prevMA) || (cur>prev && curMA<prevMA))
      {
         ExtMapBuffer3[i]=0;
         ExtMapBuffer4[i]=0;
         ExtMapBuffer5[i]=cur;
      } 
   }
//----
   return(0);
  }
//+------------------------------------------------------------------+

Надеюсь, ответил исчерпывающе. )))

Чтож, чтобы не быть голословным придется цитировать Элдера :-). Разберемся что же такое MACD (цитата из книги "Как играть и выигрывать на бирже"):

"Первоначально индикатор MACD состоял из двух линий: сплошной (именуемой линией MACD) и пунктирной (именуемой сигнальной линией). Линия MACD — это разница между двумя экспоненциальными скользящими средними. Она быстрее реагирует на изменения цен. Сигнальная линия — это скользящее сред­нее первой линии MACD, которая медленнее реагирует на изменения цен."

А теперь разберемся что же такое гистограмма MACD (цитата из той же книги):

"Гистограмма MACD позволяет оценить соотношение сил между быками и мед­ведями глубже, чем стандартный MACD. Она показывает, какая группа доми­нирует, становится ли эта группа сильнее или слабее. Это один из лучших ин­дикаторов в арсенале трейдеров.

Гистограмма MACD = Линия MACD — Сигнальная линия

Гистограмма MACD—это разность между линией MACD и сигнальной лини­ей (см. табл. 4.2), которая графически представлена рядом вертикальных стол­биков, т. е. гистограммой."

А теперь разберемся в импульсной системе (цитата из Трейдинг с доктором Элдером):

" Импульсная система строится на двух простых, но эффективных индикаторах. Один измеряет инерцию рынка, а другой — скорость изменения цен. Если оба движутся в одном направлении, это сигнал к открытию позиции. Как только они перестают подтверждать друг друга, мы получаем сигнал к закрытию позиции. Импульсная система использует экспоненциальное скользящее среднее (ЕМА), чтобы определить восходящие и нисходящие тренды. Когда ЕМА повышается, инерция в пользу быков, а когда понижается — в пользу медведей. Второй компонент системы — гистограмма MACD, наклон которой указывает на соотношение сил быков и медведей. Если гистограмма MACD повышается, значит, быки становятся сильнее, а если понижается — силу набирают медведи. Импульсная система выявляет столбики (бары), где и инерция, и скорость направлены в одну сторону. Если ЕМА и гистограмма MACD растут, значит, быки сильны и восходящий тренд усиливается. А если ЕМА и гистограмма MACD одновременно понижаются, значит, на рынке побеждают медведи. "

Повторю, мне показалось будто бы вы в своем индикаторе вместо гистограммы MACD используете линию MACD, что неправильно. Возможно я не прав, и вы используете именно гистограмму, тогда убедите меня в этом...

И наконец цитата и Вашего кода:

ind_buffer1[i]=iMA(Symbol(),FastMA_Timeframe,FastMA_Period,FastMA_Shift,FastMA_Method,FastMA_Price,i) - 
         iMA(Symbol(),SlowMA_Timeframe,SlowMA_Period,SlowMA_Shift,SlowMA_Method,SlowMA_Price,i);